subprojects {
    apply plugin: 'java'
    repositories {
        mavenCentral()
    }
}

buildscript {
    repositories {
        mavenCentral()
        jcenter()
    }
    dependencies {
        classpath 'com.eriwen:gradle-css-plugin:1.11.1'
        classpath 'com.eriwen:gradle-js-plugin:1.12.1'
        classpath 'org.akhikhl.gretty:gretty:+'
        classpath 'com.tkruse.gradle:gradle-groovysh-plugin:1.0.8'
    }
}

apply plugin: 'war'
apply plugin: 'css'
apply plugin: 'org.akhikhl.gretty'
apply plugin: 'com.eriwen.gradle.js'
apply plugin: 'com.github.tkruse.groovysh'


repositories {
    mavenCentral()
}

def core = project(':deps:com.juick')
def server = project(':deps:com.juick.server')
def xmpp = project(':deps:com.juick.xmpp')
def json = project(':deps:com.juick.json')

project(':deps:com.juick.server') {
    dependencies {
        compile core
    }
}

project(':deps:com.juick.xmpp') {
    dependencies {
        compile core
    }
}

project(':deps:com.juick.json') {
    dependencies {
	compile core
    }
}

dependencies {
    compile core
    compile server
    compile xmpp
    compile json
    compile 'org.slf4j:slf4j-jdk14:1.7.13'
    compile 'com.ganyo:gcm-server:1.0.+'
    compile 'com.notnoop.apns:apns:1.0.0.Beta6'
    compile 'com.github.scribejava:scribejava-apis:2.7.3'
    compile 'org.apache.httpcomponents:httpclient:4.5.1'
    compile 'org.apache.commons:commons-lang3:3.4'
    compile 'org.json:json:20151123'
    providedCompile 'javax.servlet:javax.servlet-api:3.1.0'
    runtime 'mysql:mysql-connector-java:5.1.37'
}

javascript.source {
    dev {
        js {
            srcDir "src/main/webapp"
            include "*.js"
        }
    }
}

combineJs {
    source = javascript.source.dev.js.files
    dest = file("${buildDir}/scripts.all.js")
}

minifyJs {
    source = combineJs
    dest = file("${buildDir}/scripts.min.js")
    sourceMap = file("${buildDir}/scripts.sourcemap.json")
}

css.source {
    dev {
        css {
            srcDir "src/main/webapp"
            include "*.css"
        }
    }
}

combineCss {
    source = css.source.dev.css.files
    dest = "${buildDir}/style.all.css"
}

minifyCss {
    source = combineCss
    dest = "${buildDir}/style.min.css"
}

assemble.dependsOn 'minifyCss'
assemble.dependsOn 'minifyJs'

compileJava.options.encoding = 'UTF-8'

gretty {
    httpPort = 8080
    contextPath = ''
    servletContainer = 'tomcat8'
}