buildscript {
    repositories {
        mavenCentral()
        jcenter()
    }
    dependencies {
        classpath 'com.github.ben-manes:gradle-versions-plugin:0.20.0'
    }
}
plugins {
    id 'org.springframework.boot' version '2.0.3.RELEASE' apply false
}
allprojects {
    repositories {
        mavenCentral()
        jcenter()
        maven { url "https://jitpack.io" }
        maven { url "https://repository.apache.org/content/repositories/snapshots/" }
        maven { url "https://oss.sonatype.org/content/repositories/snapshots" }
    }
    apply plugin: 'io.spring.dependency-management'
    dependencyManagement {
        imports {
            mavenBom org.springframework.boot.gradle.plugin.SpringBootPlugin.BOM_COORDINATES
        }
        applyMavenExclusions = false
    }

    apply plugin: 'com.github.ben-manes.versions'
    dependencyUpdates.resolutionStrategy = {
        componentSelection { rules ->
          rules.all { ComponentSelection selection ->
              boolean rejected = ['alpha', 'beta', 'rc', 'cr', 'm', 'pr', 'b'].any { qualifier ->
                  selection.candidate.version ==~ /(?i).*[.-]${qualifier}[.\d-]*/
              }
              if (rejected) {
                  selection.reject('Release candidate')
              }
          }
        }
    }
}