buildscript {
    repositories {
        mavenCentral()
        jcenter()
    }
    dependencies {
        classpath 'com.github.ben-manes:gradle-versions-plugin:0.20.0'
        classpath 'io.github.swagger2markup:swagger2markup-gradle-plugin:1.3.3'
    }
}
plugins {
    id 'org.springframework.boot' version '2.0.5.RELEASE' apply false
    id "com.moowork.node" version "1.2.0" apply false
    id("org.asciidoctor.convert") version "1.5.8.1" apply false
}

allprojects {
    repositories {
        mavenCentral()
        jcenter()
        maven { url "https://jitpack.io" }
        maven { url "https://repository.apache.org/content/repositories/snapshots/" }
        maven { url "https://oss.sonatype.org/content/repositories/snapshots" }
    }
    apply plugin: 'io.spring.dependency-management'
    dependencyManagement {
        imports {
            mavenBom org.springframework.boot.gradle.plugin.SpringBootPlugin.BOM_COORDINATES
        }
        applyMavenExclusions = false
    }

    apply plugin: 'com.github.ben-manes.versions'
    dependencyUpdates.resolutionStrategy = {
        componentSelection { rules ->
          rules.all { ComponentSelection selection ->
              boolean rejected = ['alpha', 'beta', 'rc', 'cr', 'm', 'pr', 'b'].any { qualifier ->
                  selection.candidate.version ==~ /(?i).*[.-]${qualifier}[.\d-]*/
              }
              if (rejected) {
                  selection.reject('Release candidate')
              }
          }
        }
    }
}
class GenKey extends DefaultTask {
    @OutputFile
    String keystore
    @TaskAction
    def generate() {
        ant.genkey(alias:"1", keystore:keystore.toString(), storepass:"secret", dname:"CN=localhost", keysize:2048)
    }
}

task generateDebugKey(type: GenKey) {
    keystore = "${projectDir}/juick.p12"
}