subprojects {
	apply plugin: 'java'
	repositories {
		mavenCentral()
	}
}

buildscript {
        repositories {
                mavenCentral()
		jcenter()
        }
        dependencies {
                classpath 'com.eriwen:gradle-css-plugin:1.11.1'
		classpath 'com.eriwen:gradle-js-plugin:1.12.1'
        }
}

apply plugin: 'war'
apply plugin: 'jetty'
apply plugin: 'css'
apply plugin: 'com.eriwen.gradle.js'

repositories {
	mavenCentral()
}

def core = project(':deps:com.juick')
def server = project(':deps:com.juick.server')
def xmpp = project(':deps:com.juick.xmpp')

project(':deps:com.juick.server') {
	dependencies {
		compile core
	}
}

project(':deps:com.juick.xmpp') {
        dependencies {
                compile core
        }
}

dependencies {
	compile 'org.json:json:20150729'
	compile core
	compile server
	compile xmpp
	providedCompile 'javax.servlet:javax.servlet-api:3.1.0'
}

javascript.source {
	dev {
		js {
			srcDir "src/main/webapp"
			include "*.js"
		}
	}
}

combineJs {
	source = javascript.source.dev.js.files
	dest = file("${buildDir}/scripts.all.js")
}

minifyJs {
	source = combineJs
	dest = file("${buildDir}/scripts.min.js")
	sourceMap = file("${buildDir}/scripts.sourcemap.json")
}

css.source {
	dev {
		css {
			srcDir "src/main/webapp"
			include "*.css"
		}
	}
}

combineCss {
	source = css.source.dev.css.files
	dest = "${buildDir}/style.all.css"
}

minifyCss {
	source = combineCss
	dest = "${buildDir}/style.min.css"
}

assemble.dependsOn 'minifyCss'
assemble.dependsOn 'minifyJs'

jettyRun.contextPath = ''