build.gradle


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118

subprojects {
    apply plugin: 'java'
    repositories {
        mavenCentral()
    }
}

buildscript {
    repositories {
        mavenCentral()
        jcenter()
    }
    dependencies {
        classpath 'com.eriwen:gradle-css-plugin:1.11.1'
        classpath 'com.eriwen:gradle-js-plugin:1.12.1'
        classpath 'com.bmuschko:gradle-tomcat-plugin:2.2.+'
        classpath 'com.tkruse.gradle:gradle-groovysh-plugin:1.0.7'
    }
}

apply plugin: 'war'
apply plugin: 'css'
apply plugin: 'com.bmuschko.tomcat'
apply plugin: 'com.eriwen.gradle.js'
apply plugin: 'com.github.tkruse.groovysh'


repositories {
    mavenCentral()
}

def core = project(':deps:com.juick')
def server = project(':deps:com.juick.server')
def xmpp = project(':deps:com.juick.xmpp')
def json = project(':deps:com.juick.json')

project(':deps:com.juick.server') {
    dependencies {
        compile core
    }
}

project(':deps:com.juick.xmpp') {
    dependencies {
        compile core
    }
}

project(':deps:com.juick.json') {
    dependencies {
	compile core
    }
}

dependencies {
    compile core
    compile server
    compile xmpp
    compile json
    compile 'com.ganyo:gcm-server:1.0.+'
    compile 'com.notnoop.apns:apns:1.0.0.Beta6'
    compile 'com.github.scribejava:scribejava-apis:2.0.1'
    providedCompile 'javax.servlet:javax.servlet-api:3.1.0'
    runtime 'mysql:mysql-connector-java:5.1.37'
    def tomcatVersion = '7.0.+'
    tomcat "org.apache.tomcat.embed:tomcat-embed-core:${tomcatVersion}",
            "org.apache.tomcat.embed:tomcat-embed-logging-juli:${tomcatVersion}",
            "org.apache.tomcat.embed:tomcat-embed-jasper:${tomcatVersion}"
}

javascript.source {
    dev {
        js {
            srcDir "src/main/webapp"
            include "*.js"
        }
    }
}

combineJs {
    source = javascript.source.dev.js.files
    dest = file("${buildDir}/scripts.all.js")
}

minifyJs {
    source = combineJs
    dest = file("${buildDir}/scripts.min.js")
    sourceMap = file("${buildDir}/scripts.sourcemap.json")
}

css.source {
    dev {
        css {
            srcDir "src/main/webapp"
            include "*.css"
        }
    }
}

combineCss {
    source = css.source.dev.css.files
    dest = "${buildDir}/style.all.css"
}

minifyCss {
    source = combineCss
    dest = "${buildDir}/style.min.css"
}

assemble.dependsOn 'minifyCss'
assemble.dependsOn 'minifyJs'

compileJava.options.encoding = 'UTF-8'

tomcat {
    httpPort = 8080
    contextPath = '/'
}