build.gradle


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

buildscript {
    repositories {
        mavenCentral()
        jcenter()
    }
    dependencies {
        classpath 'com.github.ben-manes:gradle-versions-plugin:0.17.0'
    }
}
plugins {
    id 'org.springframework.boot' version '2.0.0.RELEASE' apply false
}
allprojects {
    repositories {
        mavenCentral()
        jcenter()
        maven { url "https://jitpack.io" }
        maven { url "https://repository.apache.org/content/repositories/snapshots/" }
    }

    apply plugin: 'io.spring.dependency-management'
    dependencyManagement {
        imports {
            mavenBom org.springframework.boot.gradle.plugin.SpringBootPlugin.BOM_COORDINATES
        }
    }

    apply plugin: 'com.github.ben-manes.versions'
    dependencyUpdates.resolutionStrategy = {
        componentSelection { rules ->
          rules.all { ComponentSelection selection ->
              boolean rejected = ['alpha', 'beta', 'rc', 'cr', 'm', 'pr', 'b'].any { qualifier ->
                  selection.candidate.version ==~ /(?i).*[.-]${qualifier}[.\d-]*/
              }
              if (rejected) {
                  selection.reject('Release candidate')
              }
          }
        }
    }
}

apply plugin: 'java'

dependencies {
    compile project(':juick-common')

    testCompile "org.json:json:20180130"
    testCompile("org.springframework.boot:spring-boot-starter-jdbc")
    testCompile("org.springframework.boot:spring-boot-starter-test")
    testRuntime "mysql:mysql-connector-java:5.1.40"
    testRuntime "org.postgresql:postgresql:42.2.1"
}